132. Scenario Relevance KPI

# Copyright (C) 2024 Foretellix Ltd (“Foretellix”)
# This source code file is licensed to you under Foretellix’ End User License
# Agreement, you may not use this file except in compliance with the License.
# You are not allowed to distribute it to any third party without Foretellix’
# written approval.
# If you choose to modify this code (in compliance with the license terms),
# you do it at your own risk, and Foretellix will no longer supply any
# support or maintenance services for this source code.
# See the License for the specific language governing permissions and
# limitations under the License.

#----- code snippet start -----#
struct vehicle_zone_watcher_data inherits any_watcher_data:
    actor_id: int
    interval_count : int = 0
    vehicle_lon_time_gap: time 
    vehicle_lat_offset : length

    record(actor_id, text: "Unique identification number of the actor")

    record(interval_count, text: "The total interval count of the zone")

    record(vehicle_lat_offset, unit : m, 
        text: "Lateral offset of the actor relative to Ego")

    record(vehicle_lon_time_gap, unit: s, 
        text: "Londitudinal time-gap of the actor relative to Ego")

# The watcher creates intervals when any vehicle enters the respective zone conditions.
# A watcher type, ego_zone_limit_watcher_for_vehicle, is created and the watchers, 
# ego_front_left_zone_limit_watcher_for_vehicle, 
# ego_front_right_zone_limit_watcher_for_vehicle, 
# ego_back_left_zone_limit_watcher_for_vehicle, 
# and ego_back_right_zone_limit_watcher_for_vehicle, 
# are instantiated from that watcher type
watcher modifier ego_zone_limit_watcher_for_vehicle(vehicle_zone_watcher_data):

    any_actor : vehicle
    vehicle_max_time_gap_threshold  : time
    vehicle_min_time_gap_threshold  : time
    vehicle_max_lat_threshold : length 
    vehicle_min_lat_threshold : length
    ego_dist_ref: distance_reference
    vehicle_dist_ref: distance_reference
    var vehicle_lat_offset: length = 0m
    var vehicle_lon: length  = 0m
    var vehicle_lon_time_gap: time
    var i : int = 0
    var actor_id: int =0
    var interval_count: int = 0
    var vehicle_present :int = 0
    var start_time : time =0s
    var end_time : time =0s
    var move_duration: time= 0s
    var previous_total_time: time =0s
    var total_time: time =0s


    on @top.w_clk:

            # Lateral position 
            vehicle_lat_offset = sut.car.road_distance(\
            any_actor, center, center, direction: lat, route_type: road) 

            # Longitudinal position    
            vehicle_lon = sut.car.road_distance(\
                    any_actor, ego_dist_ref,vehicle_dist_ref, direction: lon, route_type: road) 
            if (sut.car.state.speed != 0kph):
                vehicle_lon_time_gap = vehicle_lon/sut.car.state.speed        

            # To emit start interval the vehicle_lat_offset should be             
            # lesser than vehicle_max_lat_threshold  and
            # greater than vehicle_min_lat_threshold  parameter values.
            # The vehicle_lon_time_gap should be lesser than
            # vehicle_max_time_gap_threshold  and greater than 
            # vehicle_min_time_gap_threshold 
            if (vehicle_lat_offset > vehicle_min_lat_threshold  and 
                vehicle_lat_offset < vehicle_max_lat_threshold  and 
                vehicle_lon_time_gap < vehicle_max_time_gap_threshold  and
                vehicle_lon_time_gap > vehicle_min_time_gap_threshold  and 
                vehicle_present == 0 and data == null):          
                        vehicle_present = 1
                        set actor_id = any_actor.uid                             
                        i = 0
                        interval_count = interval_count + 1
                        start_interval()
            # Interval ends if the vehicle_max_time_gap_threshold 
            # and vehicle_min_time_gap_threshold exceeds    
            elif not(vehicle_lon_time_gap < vehicle_max_time_gap_threshold  and
                vehicle_lon_time_gap > vehicle_min_time_gap_threshold):   
                if (vehicle_present==1 and i == 0):    
                    vehicle_present = 0
                    i= i+1
                    end_interval() 
            # Interval ends if the vehicle_max_lat_threshold 
            # and vehicle_min_lat_threshold exceeds             
            elif not(vehicle_lat_offset > vehicle_min_lat_threshold  and 
                vehicle_lat_offset < vehicle_max_lat_threshold):   
                if (vehicle_present==1 and i == 0):
                    vehicle_present = 0
                    i= i+1
                    end_interval()              

    on @i_end:
        if(data.end_time>data.start_time):
            total_time = total_time + data.end_time - data.start_time
        else :
            total_time = total_time + top.time - data.start_time

    on @i_clock:
        data.actor_id = actor_id      
        data.interval_count = interval_count 
        data.vehicle_lon_time_gap = vehicle_lon_time_gap
        data.vehicle_lat_offset = vehicle_lat_offset

global modifier npc_vehicle.ego_vehicle_zone_check:

    vehicle_min_time_gap : time = 0s
    vehicle_front_max_time_gap: time = 5s 
    vehicle_back_max_time_gap: time = -1s
    vehicle_min_lat_offset : length = 0.01m 
    vehicle_max_lat_offset : length = 5m

    watcher ego_front_left_zone_limit_watcher_for_vehicle is ego_zone_limit_watcher_for_vehicle(any_actor: actor,
        vehicle_max_time_gap_threshold : vehicle_front_max_time_gap, vehicle_min_time_gap_threshold : vehicle_min_time_gap,
        vehicle_max_lat_threshold  : vehicle_max_lat_offset, vehicle_min_lat_threshold  : vehicle_min_lat_offset, 
        ego_dist_ref: front_center, vehicle_dist_ref: back_center)
    watcher ego_front_right_zone_limit_watcher_for_vehicle is ego_zone_limit_watcher_for_vehicle(any_actor: actor, 
        vehicle_max_time_gap_threshold : vehicle_front_max_time_gap, vehicle_min_time_gap_threshold : vehicle_min_time_gap,
        vehicle_max_lat_threshold  : -1 * vehicle_min_lat_offset, vehicle_min_lat_threshold  : -1 * vehicle_max_lat_offset, 
        ego_dist_ref: front_center, vehicle_dist_ref: back_center)
    watcher ego_back_left_zone_limit_watcher_for_vehicle is ego_zone_limit_watcher_for_vehicle(any_actor: actor,
        vehicle_max_time_gap_threshold : vehicle_min_time_gap, vehicle_min_time_gap_threshold : vehicle_back_max_time_gap,
        vehicle_max_lat_threshold  : vehicle_max_lat_offset, vehicle_min_lat_threshold  : vehicle_min_lat_offset,
        ego_dist_ref: back_center, vehicle_dist_ref: front_center)
    watcher ego_back_right_zone_limit_watcher_for_vehicle is ego_zone_limit_watcher_for_vehicle(any_actor: actor,
        vehicle_max_time_gap_threshold : vehicle_min_time_gap, vehicle_min_time_gap_threshold : vehicle_back_max_time_gap,
        vehicle_max_lat_threshold  : -1 * vehicle_min_lat_offset, vehicle_min_lat_threshold  : -1 * vehicle_max_lat_offset, 
        ego_dist_ref: back_center, vehicle_dist_ref: front_center)
#----- code snippet end -----#